rev1(X,Y):-rev(X,[],Y).
rev([],X,X).
rev([A|Rest],Y,Z):-
	rev(Rest,[A|Y],Z).


rev2([],[]).
rev2([A|As],Bs):-
	reverse(As,Cs),
	append(Cs,[A],Bs).


min1(A,A,A).
min1(A,B,A):-A<B.
min1(A,B,B):-B<A.

min2(A,B,C):-C is (A+B)/2-abs((A-B)/2).

min3(A,B,C):-sort([A,B],[C|_]).

replaceOne(X,Y,[X|Rest],[Y|Rest]).
replaceOne(X,Y,[A|Rest1],[A|Rest2]):-
	replaceOne(X,Y,Rest1,Rest2).

replaceAll(_,_,[],[]).
replaceAll(X,Y,[X|Rest1],[Y|Rest2]):-
	replaceAll(X,Y,Rest1,Rest2).
replaceAll(X,Y,[A|Rest1],[A|Rest2]):-
	A\=X,
	replaceAll(X,Y,Rest1,Rest2).


sumUp1([],0).
sumUp1([A|Rest],X):-
	sumUp1(Rest,X1),
	X is X1+A.

sumUp2(L,Sum):-sumUp2(L,0,Sum).
sumUp2([],X,X).
sumUp2([A|Rest],X,Sum):-
	X1 is X+A,
	sumUp2(Rest,X1,Sum).

%fehlerhaft -- X1 muss vorher instanziiert werden
sumUp1a([],0).
sumUp1a([A|Rest],X):-
	X is X1+A,
	sumUp1a(Rest,X1).

%fehlerhaft -- Richtung ist falschrum
sumUp1b([],0).
sumUp1b([A|Rest],X):-
	X1 is X-A,
	sumUp1b(Rest,X1).


pAdd1(0,X,X).
pAdd1(X,0,X).
pAdd1(s(X),s(Y),s(s(Z))):-
	pAdd1(X,Y,Z).

pAdd2(0,X,X).
pAdd2(s(0),X,s(X)).
pAdd2(s(s(X)),Y,s(s(Z))):-
	pAdd2(X,Y,Z).