%% ein erster Versuch für die Topikalisierung von NPs aus dem
%% Mittelfeld durch einen Bewegungsmechanismus

%?- s(S,[den,schluessel,sucht,hans],[]).
%S = s(vp(np(hans, nom), np(schluessel, acc), v(sucht))) ;
%false.

%?- s(S,[hans, sucht,den,schluessel],[]).
%S = s(vp(np(hans, nom), np(schluessel, acc), v(sucht))) ;
%false.

%% Lässt Nicht-Bewegung zu, allerdings mit unerwünscher 
%% Mehrdeutigkeit (warum eigentlich?)

%?- s(S,[sucht,hans,den,schluessel],[]).
%S = s(vp(np(hans, nom), np(schluessel, acc), v(sucht))) ;
%S = s(vp(np(hans, nom), np(schluessel, acc), v(sucht))) ;
%false.

%% weitere unerwünschte Mehrdeutigkeit durch unterschiedliche
%% Instanziierungsvarianten bei der Eingabe identischer 
%% lexikalischer Elemente; wie verhindern, ohne die lexikalische
%% Unabhängigkeit der Tilgungsregel zu beseitigen?

%?- s(S,[hans,sucht,hans],[]).
%S = s(vp(np(hans, nom), np(_G3973, acc), v(sucht))) ;
%S = s(vp(np(hans, nom), np(hans, acc), v(sucht))) ;
%S = s(vp(np(hans, nom), np(hans, acc), v(sucht))) ;
%S = s(vp(np(_G3973, nom), np(hans, acc), v(sucht))) ;
%false.


       % die topikalisierte NP wird aus dem Mittelfeld 
       % extrahiert; die Satzstruktur ist identisch zur 
       % Struktur der Verbalphrase
s(s(Svp)) --> np(SlashNP,_), vp(Svp,SlashNP).

       % man kann entweder das Subjekt
vp(vp(SlashNP,Sdobj,Sv),SlashNP) 
  --> v(Sv), 
      np(SlashNP,nom),
      np(Sdobj,acc).

       % oder das Objekt extrahieren
vp(vp(Ssubj,SlashNP,Sv),SlashNP) 
  --> v(Sv), 
      np(Ssubj,nom),
      np(SlashNP,acc).
       % die Strukturbeschreibung ist in beiden Fällen 
       % identisch: vp(Subjekt,Objekt,Verb)

       % Lexikoneinträge für reale NPs 
np(np(schluessel,acc),acc) --> [den, schluessel].
np(np(hans,nom),nom) --> [hans].
np(np(hans,acc),acc) --> [hans].

       % Tilgungsregel für weggelassene NPs
np(np(_,CASE),CASE) --> []. 

       % Lexikoneintrag für das Verb
v(v(sucht)) --> [sucht].